*  JieJie Microelectronics P-Spice Model Library
*  Filename:  JMSL1010AKQ _P v.20230111.txt
*  Product Name:  JMSL1010AKQ (TO-252-3L)
*  Configuration: Single N channel Device
*  Data Sheet Rev.: 1.0
*  Release Date: January 12, 2023
*  Junction Temp (Tj): -40C ~ 175C
******************************************************************************************************
*  This model is designed as a tool to assist end user(s) to evaluate the performance
*  of the particular SGT MOSFET (named above) released by JJMSH(R).  It has been
*  verified for function and timing integrity with commercially available EDA simulation
*  tools End-user(s) is/are advised to take the best engineering practice (e.g.
*  bread-boarding, laboratory measurement) for the full evaluation.
*
*  Despite of the best effort on engineering & verification, Jiangsu JieJie Microelectronics Co.,
*  Ltd. ("JJM") does not provide any warranty nor take any liability to the results and
*  their effects whatsoever from the simulation run of this model by the end-user(s).
*  While this model may be updated at appropriate times in the future without prior
*  notice, JJM does not assume the sole responsibility for update. 
*
.subckt JMSL1010AKQ D G S 
M1 1 2 3 3 NMOS L=1E-006 W=1E-006
Vmonitor D 18 0
RD 18 1 0.007
RS S 3 1E-006
RG G 17 1.9
CGS 3 G 1.525E-9
EGD 12 0 2 1 1
Etemp 17 2 VALUE = {(-0.00328*(TEMP-25))+((-3.63739E-6)*(TEMP-25)^2)}
Gtemp 1 3 VALUE = {I(Vmonitor)*((TEMP+273)/(298)-((TEMP+273)/(298))^1.8)}
VFB 14 0 0
FFB 2 1 VFB 1
CGD 13 14 5E-10
DDG 15 14 DCGD
R2 12 15 1
D2 15 0 DLIM
DSD 3 D DSUB
RR 13 0 1
D1 12 13 DLIM
Cbreak D 3 Cbreak 1.16546E-9
.MODEL Cbreak CAP (C = 1 VC1 = -0.01793 VC2 = 9.32866E-5)

.model NMOS NMOS
+LEVEL = 3      
+VMAX = 1.0752E9               ETA = 1E-4   
+VTO = 2.5                     TOX = 8E-10       NSUB = 3.55E15   
+KP = 140                      U0 = 424         KAPPA = 0.1    
+GAMMA = 0.3                   PHI = 0.515242       THETA = 0.2     
+DELTA = 30                    

.model DCGD D
+CJO = 4.4E-10                 VJ = 12      M = 1.7   

.model DSUB D
+IS = 8E-13                    N = 1.04             RS = 3.2E-3   
+BV = 109                     xti = 2.8    
       
.model DLIM D
+IS = 1E-4    
.ends JMSL1010AKQ

******************************************************************************************************
*  Copyright (C) 2023 JJM. All rights reserved.
******************************************************************************************************

